/*
 * Copyright (c) 2020 - present Cloudogu GmbH
 *
 * This program is free software: you can redistribute it and/or modify it under
 * the terms of the GNU Affero General Public License as published by the Free
 * Software Foundation, version 3.
 *
 * This program is distributed in the hope that it will be useful, but WITHOUT
 * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
 * FOR A PARTICULAR PURPOSE. See the GNU Affero General Public License for more
 * details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program. If not, see https://www.gnu.org/licenses/.
 */

import com.cloudogu.scm.ScmManagerUploadTask

plugins {
  id 'org.scm-manager.packaging'
  id 'org.scm-manager.license'
}

configurations {
  packageYaml {
    canBeResolved = true
  }
}

dependencies {
  packageYaml project(path: ':scm-packaging:unix', configuration: 'packageYaml')
  packageYaml project(path: ':scm-packaging:windows', configuration: 'packageYaml')
  packageYaml project(path: ':scm-packaging:deb', configuration: 'packageYaml')
  packageYaml project(path: ':scm-packaging:rpm', configuration: 'packageYaml')
  packageYaml project(path: ':scm-packaging:docker', configuration: 'packageYaml')
  packageYaml project(path: ':scm-packaging:helm', configuration: 'packageYaml')
}

task distribution(type: ReleaseYaml) {
  configuration = configurations.packageYaml
}

task publish(type: ScmManagerUploadTask) {
  server = "https://ecosystem.cloudogu.com/scm"
  namespace = "scm-manager"
  repo = "website"
  path = "content/releases/${project.version.replace('.', '-')}.yml"
  branch = "master"
  message = "Add release descriptor for ${project.version}"
  artifact = file('build/libs/release.yml')
  if (project.hasProperty("ecosystemApiToken")) {
    apiToken = project.property("ecosystemApiToken")
  }
  skip = isSnapshot
  dependsOn 'distribution'
}

license {
  header rootProject.file("LICENSE-HEADER.txt")
  lineEnding = "\n"

  tasks {
    gradle {
      files.from('build.gradle')
    }
  }
}


task check {
  dependsOn checkLicenses
}